Exercise 9

Objective/Overview:

In today’s exercise, we are going to continue working with boundary conditions for the electric and displacement fields. We are going to look at the behavior of conductors in electric fields, and use the fact that electric field inside a conductor must be zero, which means that, by our boundary conditions for the tangential component of the electric field, our lateral E field at the surface of a conductor must also be zero. You will also have to remember and use Gauss’s Law, which should be good review for the Mid-Term Exam 1.

Point Charge Above  Conducting Plane

Let’s imagine we place a positive point charge Q=(Subscript[ϵ, o]) a distance of h=1m above a grounded conducting plane (at position {0,0,1}).  

We know that inside the conducting plane, we should have no electric field.  That will happen as a consequence a negative surface charge density that will be induced on top of the conducting plane to cancel the E-field of the charge within the conductor and also ascertain proper boundary conditions we expect to hold at the conductor surface --- zero tangential E-field and D_z matching the surface charge density.

The difficulty we face is the following: unless the induced surface charge density on the conductor surface is uniform, we don’t know an easy way of computing the E-field contribution coming from the surface charge.  Without that knowedge we can’t apply our boundary conditions in a direct way (except for solving Poisson’s or Laplace’s equations numerically). 

We will circumvent that difficulty by using an important principle, the principle of uniqueness for the solutions of Maxwell’s equations!  

According to this principle there is a single correct answer and if we can guess the answer by making a plausible assumption and see that Maxwell’s equations are met --- then we are done!

To illustrate how this works we will first look at the field of our positive point charge Q=(Subscript[ϵ, o]) located at position {0,0,1} on the z=0 surface of the coducting plane.  Then we will see whether we can “imagine” a partially canceling field that can ascertain the BC’s we need to satisfy.

eps0=8.85*10^-12;k=1/(4*Pi*eps0);

rvec={x,y,z};r=Norm[rvec];rhat=rvec/r;
eQo=k*eps0*rhat/r^2         (* field of charge Q=eps0 sitting at the origin *)

eQ=eQo /. z-> z-1    (* field of Q sitting at {0,0,1} *)

On the surface of the conductor, the field from the point charge is:

eQxy=eQ /. z->0

having non-zero tangential components not allowed by BS’s!!!  

Here is a plot the offensive x-component of E  at z=0:

Plot[eQxy[[1]] /. y->0,{x,-1,1},PlotRange->All]

What would eQxy be for a negative point charge Q = -(Subscript[ϵ, o]) located at position {0,0,-1}?   Could it cancel the offensive E_x plotted above?  

This question leads to the idea of ...

Method of Images

Let’s see: with IM standing for IMAGE, we will have an “image electric field”

eIM=-eQo /. z-> z+1

eIMxy=eIM /. z->0;

This “image field” on z=0 plane has equal and opposite  x and y components as the original field and the same z-component!  

Total field coming from our two charges on the z=0 plane is:

eTOTxy=eQxy+eIMxy

This has zero tangential components and a “doubled” z-component.  By uniqueness we have stumbled upon our solution!! 

The total E-field above the z=0 plane is:

eTOT=eQ+eIM

Surface charge density is

eps0*eTOTxy[[3]]

ContourPlot[eps0*eTOTxy[[3]],{x,-2,2},{y,-2,2},PlotRange->All,PlotLegends->Automatic]

VectorPlot3D[eTOT,{x,-2,2},{y,-2,2},{z,0,4},VectorStyle->Arrowheads[0.015]] (* plot above the surface *)

VectorPlot3D[eTOT,{x,-2,2},{y,-2,2},{z,-2,2},VectorStyle->Arrowheads[0.015]] (* also showing the image *)

Method of Images (2)

The method of images is a very powerful technique for calculating fields in the vicinity of conducting surfaces.  

Now it’s your turn to use this technique!  

Calculate the electric field of a charged wire sitting a distance z=2 above a conducting plate held at V=0.  

Assume the wire is infinite in the y-direction, and is at x=0.  You can assume whatever linear charge density you like for the line of charge.  Plot the vector field for the system in the xz plane.